Заставка и предзаставка

Добавление заставки

Заставка (splash screen) — это изображение или видео, которое появляется при запуске игры до перехода в главное меню. Обычно это логотипы или вступительные видео. Метка "splashscreen" автоматически воспроизводится перед главным меню. Однако тот же код применим к заставке, расположенной в любом другом месте вашей игры под другой меткой.

Чтобы добавить текстовую заставку в вашу игру, вставьте код, подобный приведенному ниже, в любое место ваших файлов скриптов (главное, чтобы он не находился внутри другого блока):

label splashscreen:
    scene black
    with Pause(1)

    show text "American Bishoujo Presents..." with dissolve
    with Pause(2)

    hide text with dissolve
    with Pause(1)

    return

Вот еще один пример заставки, на этот раз с использованием изображения и звука:

image splash = "splash.png"

label splashscreen:
    scene black
    with Pause(1)

    play sound "ping.ogg"

    show splash with dissolve
    with Pause(2)

    scene black with dissolve
    with Pause(1)

    return

И, наконец, с видеофайлом:

label splashscreen:

    $ renpy.movie_cutscene('movie.ogv')

    return

Добавление предзаставки

Предзаставка (presplash) — это изображение, показываемое, пока Ren'Py читает скрипты и запускает игру. Чтобы показать такое изображение во время запуска движка, создайте файл изображения с именем presplash.png (или presplash.jpg) и сохраните его в папку game.

presplash.png: Изображение, которое используется при загрузке игры.

Это будет работать только на компьютерных платформах, но не на Android, iOS или в вебе. Для платформы Android см. Предзагрузочный экран (Presplash), а для веба — см. Web Presplash.

Переменная config.minimum_presplash_time устанавливает минимальное время показа предзаставки.

Добавление индикатора загрузки

Вместо статичного изображения также можно показать индикатор выполнения, отражающий прогресс загрузки движка. Это заменяет обычное изображение предзаставки и будет автоматически иметь приоритет, если предоставлены оба варианта.

Индикатор загрузки можно настроить, для этого вам нужно предоставить два файла в формате PNG или JPG:

presplash_background.png: Фоновое изображение индикатора загрузки. Оно показывается полностью во время запуска, поэтому его можно использовать для создания любого фона для индикатора, например, добавив рамку или сплошной фон. Оно всегда должно быть полностью непрозрачным.
presplash_foreground.png: Изображение переднего плана индикатора загрузки. Оно проявляется слева направо во время загрузки. Его следует использовать для создания внешнего вида самого индикатора. Может содержать прозрачность.

Это работает следующим образом: Ren'Py сначала покажет presplash_background.png, а затем поверх него отрисует presplash_foreground.png, проявляя его слева направо по мере загрузки.

Оформление индикатора полностью зависит от вас, но ниже вы можете найти два примера того, как это может выглядеть:

_images/presplash_background_1.png — Пример того, как может выглядеть фон индикатора загрузки.

_images/presplash_foreground_1.png — Пример того, как может выглядеть передний план индикатора загрузки.

_images/presplash_background_2.png — Немного более сложный пример того, как может выглядеть фон индикатора загрузки.

_images/presplash_foreground_2.png — Немного более сложный пример того, как может выглядеть передний план индикатора загрузки.

Прозрачная предзаставка

Если левый верхний пиксель фонового изображения предзаставки прозрачен, окно предзаставки также будет прозрачным. Используется 1-битная прозрачность: пиксели с альфа-каналом 0 становятся прозрачными, а все остальные — непрозрачными.

Мобильные и веб-предзаставки

Платформы Android, iOS и Web имеют свои собственные предзаставки. Они документированы в других разделах: